# Maintainer: Twann <tw4nn at disroot.org>

# Warning: this is a version of TBlock GUI without its dependency on polkit.
# If you are looking for the official package, please install tblock-gui from the AUR.

pkgname=tblock-gui
_bin_ver=1.3.4
_build_type=nopolkit.0
pkgver=${_bin_ver}.${_build_type}
pkgrel=1
provides=("$pkgname")
pkgdesc="Official graphical user interface for the TBlock content blocker"
url="https://tblock.me"
arch=("any")
license=("GPL3")
makedepends=(
        "make"
        "python>=3"
        "python-setuptools"
        "git"
    "gettext"
)
depends=(
        "gtk3"
    "glib2"
        "python-gobject"
        "hicolor-icon-theme"
        "coreutils"
        "tblock"
)
source=(
        "${pkgname}-${_bin_ver}.tar.gz::https://codeberg.org/tblock/tblock-gui/archive/${_bin_ver}.tar.gz"
)
sha512sums=(
    "f0f6a0d5ea09da188cd3a2dfe432e63f6a614eae94155f0da39c8d0fdd92eff604b100222c369a308eb1d4b923d5214b5026e6ae67518d8697c9c27f3078d528"
)

prepare()
{
    cd "$srcdir/$pkgname"
    patch -p1 -i data/patch/no-polkit.patch
}

build()
{
        cd "$srcdir/$pkgname"
        make
}

package()
{
        cd "$srcdir/$pkgname"
        # Install the package
        make install ROOT="$pkgdir"
        rm -vr "$pkgdir/usr/share/polkit-1/"
}