# Maintainer (Arch): Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Maintainer (Arch): Dan McGee <dan@archlinux.org>
# Maintainer: André Silva <emulatorman@hyperbola.info>

pkgname=libarchive
pkgver=3.3.3
_debver=3.3.3
_debrel=4+deb10u1
pkgrel=1.hyperbola5
pkgdesc='Multi-format archive and compression library, with libressl support and without support for zstd'
arch=(i686 x86_64)
url='https://libarchive.org/'
license=(Simplified-BSD)
depends=(acl attr bzip2 expat lz4 libressl xz zlib)
makedepends=(quilt)
provides=(libarchive.so)
source=("https://libarchive.org/downloads/$pkgname-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/liba/libarchive/libarchive_$_debver-$_debrel.debian.tar.xz")
sha512sums=('9d12b47d6976efa9f98e62c25d8b85fd745d4e9ca7b7e6d36bfe095dfe5c4db017d4e785d110f3758f5938dad6f1a1b009267fd7e82cb7212e93e1aea237bab7'
            '8896c0a06535f41ba86669fc407f7c4091e0fbf0a6adf2f2cec33afa7c68dd944563e92eb87cec978cb6e89ee3bd64b4fafe7692d062bd3c416fb7afdbd48182')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -fi
}

build() {
  cd $pkgname-$pkgver
  ./configure \
      --prefix=/usr \
      --without-xml2 \
      --without-nettle \
      --without-zstd \
      --disable-static

  make
}

check() {
  cd $pkgname-$pkgver
  make check
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/libarchive/COPYING"
}