# Maintainer (Arch): Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer (Arch): Eric Bélanger <eric@archlinux.org>
# Maintainer: André Silva <emulatorman@hyperbola.info>
# Contributor: Tobias Dausend <throgh@hyperbola.info>

pkgbase=avidemux
pkgname=('avidemux-cli' 'avidemux-qt')
pkgver=2.7.8
pkgrel=1
pkgdesc='Graphical tool to edit video (filter/re-encode/split)'
url='http://fixounet.free.fr/avidemux/'
arch=('i686' 'x86_64')
license=('GPL-2')
makedepends=('cmake' 'libxslt' 'qt-base' 'jack' 'libvorbis' 'libxv' 'opus' 'desktop-file-utils'
             'alsa-lib' 'lame' 'xvidcore' 'faad2' 'x264' 'x265' 'libsamplerate' 'libmad'
             'opencore-amr' 'yasm' 'mesa' 'libvpx' 'libsndio' 'libva' 'intltool' 'sqlite'
             'libvdpau' 'libdca' 'fribidi' 'glu' 'qt-tools' 'twolame'  'libass'
             'libmp4v2' 'a52dec' 'aften' 'dcaenc')
options=('!emptydirs')
source=(https://downloads.sourceforge.net/avidemux/avidemux_${pkgver}.tar.gz
        log.diff
        qt-5.15.diff)
sha512sums=('d936eb005a8418b8f3081fce599cd04bb1a256bb7cb4bf50bf2ed876658881ca76b8c6f3805da9f05614eea44eaf2d53da0f802b28ce76e754b738f2682df031'
            'bbae5b4a549113b12e728c4c0ac8c1c92a0b7500be8dcecc791c16c9a913406feaa9f7bc477985970a920d2df391cc9392457512d84b9c4b829981cc072f2b2e'
            'ed78c2a3e4ede4fed1d3ea353c7dc350dc73050f76c8112cb24d97b3eda01f7c186d5db199f71f56953c5e5d8104de44dc0e84e1bfa01b6647c050c11fc375f2')

prepare() {
  cd ${pkgbase}_${pkgver}
  patch -Np1 -i ../log.diff  # don't hide the build output
  patch -Np1 -i ../qt-5.15.diff  # fix build against Qt 5.15.0

  sed -i 's|../avidemux/qt4|../avidemux/qt4 -DLRELEASE_EXECUTABLE=/usr/bin/lrelease-qt5|' bootStrap.bash
  sed -e 's|0.19|1.0|' -i avidemux_plugins/ADM_videoFilters6/ass/CMakeLists.txt
  sed -i 's|faacDecInit|NeAACDecInit|' cmake/admCheckFaad.cmake # detect faad2 correct
}

build() {
  if [[ $CARCH = "i686" ]]; then
    export CXXFLAGS="-Og"
    export CFLAGS="-Og"
  fi

  cd ${pkgbase}_${pkgver}
  bash bootStrap.bash \
    --with-core \
    --with-cli \
    --with-qt \
    --with-plugins \
    --with-system-libass \
    --with-system-libmad \
    --with-system-libmp4v2 \
    --with-system-liba52
}

package_avidemux-cli() {
  depends=('libxml2' 'fontconfig' 'sqlite' 'libvpx' 'libva' 'libvdpau')
  optdepends=('lame: for the corresponding audio encoder plugin'
              'faad2: for the corresponding audio decoder plugin'
              'opus: for the corresponding audio decoder plugin'
              'opencore-amr: for the corresponding audio decoder plugin'
              'a52dec: for the corresponding audio decoder plugin'
              'jack: for the corresponding audio device plugin'
              'libsndio: for the corresponding audio device plugin'
              'x264: for the corresponding video encoder plugin'
              'libx264: for the corresponding video encoder plugin'
              'libmp4v2: for the corresponding video encoder plugin'
              'x265: for the corresponding video encoder plugin'
              'xvidcore: for the corresponding video encoder plugin'
              'qt-base: for the QtScript scripting support'
              'libdca: for the corresponding audio decoder plugin'
              'twolame: for the corresponding audio decoder plugin'
              'libass: for the corresponding video filter plugin'
              'fribidi: for the corresponding video filter plugin'
              'aften: for the corresponding audio device plugin' 
              'dcaenc: for the corresponding audio device plugin')

  cd ${pkgbase}_${pkgver}
  make -C buildCli DESTDIR="${pkgdir}" install
  make -C buildCore DESTDIR="${pkgdir}" install
  make -C buildPluginsCLI DESTDIR="${pkgdir}" install
  make -C buildPluginsCommon DESTDIR="${pkgdir}" install

  install -Dm 644 avidemux_icon.png "${pkgdir}/usr/share/pixmaps/avidemux.png"
  install -Dm 644 man/avidemux.1 -t "${pkgdir}/usr/share/man/man1"

  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}

package_avidemux-qt() {
  pkgdesc='Graphical tool to edit video (filter/re-encode/split) - Qt GUI'
  depends=("avidemux-cli=${pkgver}" 'qt-base' 'x264' 'x265' 'glu' 'libxv' 'desktop-file-utils')

  cd ${pkgbase}_${pkgver}
  make -C buildQt5 DESTDIR="${pkgdir}" install
  make -C buildPluginsQt5 DESTDIR="${pkgdir}" install

  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}