<![CDATA[HyperForum — [Collection] Compilation of packages and ports (not in repositories)]]> 2026-08-17T17:03:44Z PunBB https://forums.hyperbola.info/viewtopic.php?id=773 <![CDATA[Re: [Collection] Compilation of packages and ports (not in repositories)]]> Package dfm

PKGBUILD

# Maintainer: Tobias Dausend <throgh@hyperbola.info>

pkgname=dfm
pkgver=1.0.2
pkgrel=1
pkgdesc="File-manager for the console"
arch=('i686' 'x86_64')
license=('Expat')
depends=('glibc')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/dylanaraps/dfm/archive/refs/tags/${pkgver}.tar.gz")
sha512sums=('4a85eb2d98609c9f9c63b5f3e3b596f9c522ae799956a3cc6a1dff9210f6bb54a63ba945972e56154c198c35487d852b477648dc7791af4b567b549ffe556541')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  CFLAGS+=' -static'
  ./configure \
    --prefix=/usr
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  install -Dm755 $pkgname -t "$pkgdir/usr/bin"
  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}
]]> https://forums.hyperbola.info/profile.php?id=347 2026-08-17T17:03:44Z https://forums.hyperbola.info/viewtopic.php?pid=8964#p8964 <![CDATA[Re: [Collection] Compilation of packages and ports (not in repositories)]]> Package netrik

PKGBUILD

# Maintainer (Arch): aksr <aksr at t-com dot me>
# Contributor (Arch): Sébastien Leduc <sebastien@sleduc.fr>
# Contributor (Arch): Sven Schulz <omee@archlinux.de>
# Contributor (Arch): Christoph Zeiler <rabyte@gmail.com>
# Contributor (Arch): Leslie P. Polzer <polzer@gnu.org>
# Maintainer: Tobias Dausend <throgh@hyperbola.info>

pkgname=netrik
pkgver=1.16.1
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc="Free and libre HTML-Viewer"
license=('GPL-2')
depends=('readline')
source=("https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz")
sha512sums=('73e754f8ce34226446b47c9438fb45dcc094c19ca8a2933a6cc68ed32e9cf40c9ace3189c8e63bd4537d286b608c515efd8433f795d4238ad30bd6612dd850e7')
 
prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  sed -i -e 's#<ncursesw/curses.h>#<curses.h>#g' main.c colors-dark.c colors-bright.c links.c pager.c parse-syntax.c render.c screen.c
  sed -i -e 's#<ncursesw/term.h>#<term.h>#g' render.c screen.c
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./configure \
    --prefix=/usr
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make prefix="$pkgdir/usr" install
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}
]]> https://forums.hyperbola.info/profile.php?id=347 2026-08-15T01:23:41Z https://forums.hyperbola.info/viewtopic.php?pid=8963#p8963 <![CDATA[Re: [Collection] Compilation of packages and ports (not in repositories)]]> Package heimdal

An alternative implementation of Kerberos

# Maintainer (Arch):
# Maintainer: Allen123456hello

pkgname=heimdal
pkgver=7.8.git20221117.28daf24
_debver=7.8.git20221117.28daf24
_debrel=12
pkgrel=1
pkgdesc="An alternative implementation of Kerberos and PKIX"
arch=('i686' 'x86_64')
url='https://www.heimdal.software/'
license=('Simplified-BSD' 'CC-BY-SA-3.0')
depends=('libldap' 'keyutils' 'perl-json' 'libcap-ng' 'readline' 'sqlite')
makedepends=('quilt')
#provides=('krb5')
#conflicts=('krb5')
options=('!emptydirs')
source=("https://deb.debian.org/debian/pool/main/h/heimdal/heimdal_${_debver}+dfsg.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/h/heimdal/heimdal_${_debver}+dfsg-${_debrel}.debian.tar.xz")
sha512sums=('c3e7518fd25b82320f82888c8be590cc7b61d9042c9439762eb7e3676f74595922f3429e0791f27f9b777be7cff882e003c2e72807a6ecd130665dd4148c59e6'
            'b3ecbc608e6578d24e767259e853fe2dd893aa3b9b2825c9b3ad6896408798f3f9c19100cc67fc46a4ad6668c57765b8716d7c693bd94406592f0dc0d11dc3ae')

prepare() {
  cd ${srcdir}/${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -rv debian/patches/021_debian || true
    rm -rv debian/patches/041_hurd_maxhostnamelen || true
    rm -rv debian/patches/042_hurd_path_max || true
    rm -rv debian/patches/046_hurd_sundevdata || true

    quilt push -av
  fi

  ./autogen.sh
}

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  ./configure --prefix=/usr \
              --sysconfdir=/etc \
              --localstatedir=/var/lib \
              --enable-shared \
              --enable-hdb-openldap-module \
              --enable-kcm
  make
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install

  # move conflicting files
  mv $pkgdir/usr/bin/pagsh $pkgdir/usr/bin/kpagsh
  mv $pkgdir/usr/bin/su $pkgdir/usr/bin/ksu
  mv $pkgdir/usr/share/man/man1/pagsh.1 $pkgdir/usr/share/man/man1/kpagsh.1
  mv $pkgdir/usr/share/man/man1/su.1 $pkgdir/usr/share/man/man1/ksu.1

  install -Dm644 "${srcdir}"/${pkgname}-${pkgver}/LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}
]]> https://forums.hyperbola.info/profile.php?id=755 2026-08-14T12:51:24Z https://forums.hyperbola.info/viewtopic.php?pid=8962#p8962 <![CDATA[Re: [Collection] Compilation of packages and ports (not in repositories)]]> Package got

An alternative to git.

# Maintainer (Arch): Adrian Perez de Castro <aperez@igalia.com>
# Maintainer: Allen123456hello

# Based on the gameoftrees package

pkgname=got
pkgver=0.127
pkgrel=1
pkgdesc='A version control system which prioritizes ease of use and simplicity over flexibility'
arch=(i686 x86_64)
url="https://gameoftrees.org"
license=('Modified-BSD')
provides=('got-vcs' 'gameoftrees')
replaces=('got-vcs' 'gameoftrees')
conflicts=('got-vcs' 'gameoftrees')
depends=(ncurses util-linux-libs libbsd libevent zlib libressl)
makedepends=(pkg-config git)
source=("https://gameoftrees.org/releases/portable/got-portable-$pkgver.tar.gz")
sha512sums=('94fa9602cd38bd1be18529669ac781039252b989db4515a9a05cc3cb25488403b163f178c33595306b84f7931e89183873eb586b4ec9048677fabf5bab37a0b6')

prepare () {
  cd "got-portable-$pkgver"
  # fix typo
  mv LICENCE LICENSE
}

build () {
  cd "got-portable-$pkgver"
  ./configure --prefix=/usr --with-gotd-empty-path=/var/empty
  make
}

package () {
  cd "got-portable-$pkgver"
  make DESTDIR="$pkgdir" install
  # license
  install -Dm644 "$srcdir/got-portable-$pkgver/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname"
}
]]> https://forums.hyperbola.info/profile.php?id=755 2026-08-13T14:48:32Z https://forums.hyperbola.info/viewtopic.php?pid=8961#p8961 <![CDATA[Re: [Collection] Compilation of packages and ports (not in repositories)]]> Package lolcat-c

PKGBUILD

# Maintainer (Arch): Ricardo (XenGi) Band <email@ricardo.band>
# Maintainer: Allen123456hello

pkgname=lolcat-c
_pkgname=lolcat
pkgver=1.4
pkgrel=1
pkgdesc="High-performance implementation of lolcat"
arch=('i686' 'x86_64')
url="https://github.com/jaseg/lolcat"
license=('WTFPL')
provides=('lolcat')
replaces=('lolcat')
conflicts=('lolcat')
source=("https://github.com/jaseg/${_pkgname}/archive/v${pkgver}.tar.gz")
sha512sums=('8f73121ef372383f5ff1d444f69a6255f5ff65abfbb4f103197480f957dcc440375c7c01be5c33247ce920ff39e34519702f7550b9b8ada2f18190d0ae948024')

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  make
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  mkdir -p "${pkgdir}/usr/bin"
  make DESTDIR="${pkgdir}/usr/bin" install
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/$pkgname"
}
]]> https://forums.hyperbola.info/profile.php?id=755 2026-05-23T11:49:42Z https://forums.hyperbola.info/viewtopic.php?pid=8891#p8891 <![CDATA[Re: [Collection] Compilation of packages and ports (not in repositories)]]> Package linux-libre-lts-api-headers-without-rsync

An alternative way to build kernel api headers (without rsync).

PKGBUILD

# Maintainer: André Silva <emulatorman@hyperbola.info>
# Contributor: Tobias Dausend <throgh@hyperbola.info>
# Contributor (Parabola): Luke Shumaker <lukeshu@sbcglobal.net>
# Maintainer: Allen123456hello

# Based on linux-api-headers package

# toolchain build order: linux-libre-lts-api-headers-without-rsync->glibc->binutils->gcc->binutils->glibc

pkgname=linux-libre-lts-api-headers-without-rsync
_pkgbasever=5.10-gnu1
_pkgver=${_pkgbasever}

_srcname=linux-${_pkgbasever%-*}
pkgver=${_pkgver//-/_}
pkgrel=2
pkgdesc="Kernel headers sanitized for use in userspace"
arch=('i686' 'x86_64')
url="https://www.gnu.org/software/libc"
license=('GPL-2')
provides=('linux-api-headers' 'linux-libre-lts-api-headers')
conflicts=('linux-api-headers' 'linux-libre-lts-api-headers')
replaces=('linux-api-headers')
source=("https://linux-libre.fsfla.org/pub/linux-libre/releases/${_pkgbasever}/linux-libre-${_pkgbasever}.tar.lz"
        "https://linux-libre.fsfla.org/pub/linux-libre/releases/${_pkgbasever}/linux-libre-${_pkgbasever}.tar.lz.sign")
        #"https://linux-libre.fsfla.org/pub/linux-libre/releases/${_pkgver}/patch-${_pkgbasever}-${_pkgver}.lz"
        #"https://linux-libre.fsfla.org/pub/linux-libre/releases/${_pkgver}/patch-${_pkgbasever}-${_pkgver}.lz.sign")
sha512sums=('b16238c8b746bc9b5078c991847909eba268221f945fb55579e99fc9540b88ccfca5d71f4249f4d3795c522570c30477c986f0f4b98c4029cca1235786c7bc52'
            'SKIP')
validpgpkeys=(
              '474402C8C582DAFBE389C427BCB7CF877E7D47A7' # Alexandre Oliva
)

prepare() {
  cd "${srcdir}/${_srcname}"

  # add upstream patch
  if [ "${_pkgbasever}" != "${_pkgver}" ]; then
    patch -p1 -i "${srcdir}/patch-${_pkgbasever}-${_pkgver}"
  fi
}

build() {
  cd "${srcdir}/${_srcname}"

  make mrproper

  make headers
}

package() {
  cd "${srcdir}/${_srcname}"
  # clean-up unnecessary files generated before install
  find usr/include -type f ! -name '*.h' -delete

  install -d "${pkgdir}/usr"
  cp -rv usr/include "${pkgdir}/usr"

  # use headers from libdrm
  rm -r "${pkgdir}"/usr/include/drm
  
  # clean-up unnecessary files generated during install
  find "${pkgdir}" \( -name .install -o -name ..install.cmd \) -delete

  # install license file
  install -dm755 "${pkgdir}/usr/share/licenses/$pkgname"
  install -m644 COPYING "${pkgdir}/usr/share/licenses/$pkgname"
}
]]> https://forums.hyperbola.info/profile.php?id=755 2026-05-10T11:20:50Z https://forums.hyperbola.info/viewtopic.php?pid=8875#p8875 <![CDATA[Re: [Collection] Compilation of packages and ports (not in repositories)]]> Package pkgconf

May be an alternative to pkg-config.

PKGBUILD

# Maintainer: Allen123456hello

pkgname=pkgconf
pkgver=2.5.1
pkgrel=1
pkgdesc="A newer system for managing library compile/link flags"
url="https://github.com/pkgconf/pkgconf"
license=(ISC)
arch=(i686 x86_64)
depends=(glibc)
provides=(pkg-config pkgconfig)
conflicts=(pkg-config)
source=("https://distfiles.ariadne.space/pkgconf/${pkgname}-${pkgver}.tar.xz")
sha512sums=('e654c3a460e5f0f801e8ac43ad9086f397d1da0553186ff05f5f0e18ffdac99fb652fd9b6c0379db4bc8307699699d69bc66d13cc85a4a6b0cd36462f5948a1d')

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --disable-static --docdir=/usr/share/doc/$pkgname-$pkgver 
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  ln -sv pkgconf "$pkgdir/usr/bin/pkg-config"
  ln -sv pkgconf.1 "$pkgdir/usr/share/man/man1/pkg-config.1"
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}
]]> https://forums.hyperbola.info/profile.php?id=755 2026-05-04T12:01:08Z https://forums.hyperbola.info/viewtopic.php?pid=8868#p8868 <![CDATA[Re: [Collection] Compilation of packages and ports (not in repositories)]]> Package catgirl

PKGBUILD

# Maintainer (Arch): Sebastian LaVine <mail@smlavine.com>
# Contributor (Arch): lillian rose winter <hi@neko.vg>
# Contributor (Arch): Evan McCarthy <evan@mccarthy.mn>
# Maintainer: Tobias Dausend <throgh@hyperbola.info>

pkgname=catgirl
_pkgver=2.2a
pkgver=2.2.a
pkgrel=1
pkgdesc="TLS-only terminal IRC client"
arch=('i686' 'x86_64')
url='https://git.causal.agency/catgirl/'
license=('GPL-3')
depends=('libressl' 'ncurses')
source=("https://git.causal.agency/${pkgname}/snapshot/${pkgname}-${_pkgver}.tar.gz")
sha512sums=('988750c960630ec8314ebde7b9802f8b6a3087f733359f61f49c4f83cb6e327c03cde9ad88f2cb535d56ead1376cd121a7124c367c90394a6d4d7f80b25e329f')

build() {
  cd "${pkgname}-${_pkgver}"
  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man
  make all
}

package() {
  cd "${pkgname}-${_pkgver}"
  make DESTDIR="$pkgdir/" install
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/$pkgname"
}
]]> https://forums.hyperbola.info/profile.php?id=347 2026-05-02T22:26:23Z https://forums.hyperbola.info/viewtopic.php?pid=8866#p8866 <![CDATA[Re: [Collection] Compilation of packages and ports (not in repositories)]]> Package emwm

PKGBUILD

# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Maintainer: Tobias Dausend <throgh@hyperbola.info>

pkgname=emwm
pkgver=1.3.1
pkgrel=1
pkgdesc="Free and libre fork of the Motif Window Manager"
arch=('i686' 'x86_64')
url='https://fastestcode.org/emwm.html'
license=('LGPL-2.1')
depends=('glibc' 'libx11' 'libxext' 'libxinerama' 'libxrandr' 'libxt' 'motif')
source=("https://fastestcode.org/dl/emwm-src-$pkgver.tar.xz"
        "emwm.desktop")
sha512sums=('2370aef68d4524991d188786d75d3e5a223a477ac665244d7a764c536fe6bac76207a352f55e5b1408f9b7d7192599ddb54207ebff6660f5aa4598356997b175'
            'd1193bfdf2f6245d6836123f0da0845db6e30340aaca54048a814c304a00ad94c36bc89f6b2584ea13b5a66c467910f9bb8b30a70db6b9c85c5460fc986775dc')

build() {
  cd "$pkgname-src-$pkgver"
  make
}

package () {
  cd "$pkgname-src-$pkgver"
  install -dm755 "$pkgdir/usr/bin"
  make PREFIX="$pkgdir/usr" RCDIR="$pkgdir/etc/X11" APPLRESDIR="$pkgdir/etc/X11/app-defaults" install
  install -Dm644 -t "$pkgdir/usr/share/xsessions" "$srcdir/emwm.desktop"
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}

emwm.desktop

[Desktop Entry]
Encoding=UTF-8
Type=XSession
Exec=/usr/bin/emwm
TryExec=/usr/bin/emwm
Name=EMWM
]]> https://forums.hyperbola.info/profile.php?id=347 2026-04-15T21:27:09Z https://forums.hyperbola.info/viewtopic.php?pid=8855#p8855 <![CDATA[Re: [Collection] Compilation of packages and ports (not in repositories)]]> Package motif (former openmotif)

PKGBUILD

# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor (Arch): Enrico Morelli <morelli@cerm.unifi.it>
# Maintainer: Tobias Dausend <throgh@hyperbola.info>

pkgname=motif
pkgver=2.5.1
pkgrel=1
pkgdesc="GUI component toolkit"
arch=('i686' 'x86_64')
url='https://sourceforge.net/projects/motif/'
license=('LGPL-2.1')
depends=('libxp' 'libxft' 'libxmu' 'libpng' 'libjpeg-turbo' 'libxpm')
makedepends=('xenocara-xbitmaps' 'xenocara-proto' 'quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/thentenaar/motif/archive/refs/tags/v${pkgver}.tar.gz"
        "fix-build.patch")
sha512sums=('8550b9e3a67f3c6d0aa285d9e2cdfe90df9d355ee72dc2204aba39446f27aff18ddd3b078ea5e33658086d1d53af1442c2772e953fb306f51a605f3ebb2871d8'
            '1640b5c99ac4c416ef474ef0a21b8e406b82b264bda49cff6ea09165dc90a377b17d3456ea4751e46b650130d267f3cbf901ee0decf7771ad7f40f25d124c741')

prepare() {
  cd "$pkgname-$pkgver"
  patch -Np1 -i ${srcdir}/fix-build.patch
  touch NEWS AUTHORS
  autoreconf -if
}

build() {
  cd "$pkgname-$pkgver"
  ./configure \
    --prefix=/usr
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/$pkgname"
}

fix-build.patch

--- a/lib/Xm/ImageCache.c    2026-03-28 19:09:13.000000000 +0100
+++ b/lib/Xm/ImageCache.c    2026-04-15 23:06:47.589673867 +0200
@@ -1927,9 +1927,6 @@
  * Count trailing zeroes
  */
 static unsigned int ctz(unsigned long n) {
-#if defined(__has_builtin) && __has_builtin(__builtin_ctzl)
-    return __builtin_ctzl(n);
-#else
     static const unsigned int mod37[] = {
         -1, 0, 1, 26, 2, 23, 27, 0, 3, 16, 24, 30, 28, 11, 0, 13, 4,
         7, 17, 0, 25, 22, 31, 15, 29, 10, 12, 6, 0, 21, 14, 9, 5,
@@ -1937,26 +1934,16 @@
     };
 
     return mod37[(-n & n) % 37];
-#endif
 }
 
 /**
  * Count the number of bits set in a long
  */
 static unsigned int ones(unsigned long n) {
-#if defined(__has_builtin) && __has_builtin(__builtin_popcountl)
-    return __builtin_popcountl(n);
-#elif sizeof(unsigned long) == 8
-    n = n - ((n >> 1) & 0x5555555555555555);
-    n = (n & 0x3333333333333333) + ((n >> 2) & 0x3333333333333333);
-    n = (n + (n >> 4)) & 0x0F0F0F0F0F0F0F0F;
-    return (n * 0x0101010101010101) >> 56;
-#else
     n = n - ((n >> 1) & 0x55555555);
     n = (n & 0x33333333) + ((n >> 2) & 0x33333333);
     n = (n + (n >> 4)) & 0x0F0F0F0F;
     return (n * 0x01010101) >> 24;
-#endif
 }
 
 /**
]]> https://forums.hyperbola.info/profile.php?id=347 2026-04-15T21:26:20Z https://forums.hyperbola.info/viewtopic.php?pid=8854#p8854 <![CDATA[Re: [Collection] Compilation of packages and ports (not in repositories)]]> aloniv wrote:

I noticed that no NZB usenet downloader was available in Hyperbola and I remembered using NZBGet in the past.

The PKGBUILD needed is based on the official Arch one - one just needs to disable openssl, remove the systemd path and rename unrar to unar:

PKGBUILD

# Maintainer: Jaroslav Lichtblau <svetlemodry@archlinux.org>
# Maintainer: Carl Smedstad <carsme@archlinux.org>
# Contributor: Alexander Rødseth <rodseth@gmail.com>

pkgname=nzbget
pkgver=25.4
pkgrel=2
pkgdesc="Efficient usenet downloader"
arch=('x86_64')
url="https://nzbget.com"
license=('GPL-2.0-or-later')
depends=(
  'boost-libs'
  'gcc-libs'
  'glibc'
  'libxml2'
  'ncurses'
  'zlib'
)
makedepends=(
  'boost'
  'cmake'
  'git'
)
optdepends=(
  'python: to run included scripts'
  'unar: unpacking archives'
  '7zip: unpacking archives'
)
source=(
  "https://github.com/nzbgetcom/nzbget/archive/v$pkgver/$pkgname-$pkgver.tar.gz"
  "git+https://github.com/nzbgetcom/par2cmdline-turbo.git"
  "$pkgname-use-par2cmdline-turbo-from-sources.patch"
)
sha256sums=('2603116ffaef4992621cf7a82ce300f41a676a312de784f2bac5058abc1a2385'
            'SKIP'
            '9608a7166969593fea35c2db61a788a0c0083dece1907fcc33c978c70226ff0a')

prepare() {
  cd $pkgname-$pkgver
  patch -Np1 < ../$pkgname-use-par2cmdline-turbo-from-sources.patch
}

build() {
  cd $pkgname-$pkgver
  cmake -S . -B build \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -Wno-dev \
    -DENABLE_TESTS=ON \
    -DDISABLE_TLS=ON
  cmake --build build
}

check() {
  cd $pkgname-$pkgver
  ctest --test-dir build --output-on-failure
}

package() {
  cd $pkgname-$pkgver
  DESTDIR="$pkgdir" cmake --install build
  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" ./*.md
}

nzbget-use-par2cmdline-turbo-from-sources.patch

diff --unified --recursive --text --new-file nzbget-25.3.orig/cmake/par2-turbo.cmake nzbget-25.3/cmake/par2-turbo.cmake
--- nzbget-25.3.orig/cmake/par2-turbo.cmake    2025-09-01 20:50:58.443363400 +0200
+++ nzbget-25.3/cmake/par2-turbo.cmake    2025-09-01 20:51:31.722598503 +0200
@@ -51,7 +51,7 @@
 ExternalProject_add(
     par2-turbo
     PREFIX            par2-turbo
-    GIT_REPOSITORY    https://github.com/nzbgetcom/par2cmdline-turbo.git
+    GIT_REPOSITORY    file://${CMAKE_SOURCE_DIR}/../par2cmdline-turbo
     GIT_TAG            v1.3.0-20250808
     TLS_VERIFY        TRUE
     GIT_SHALLOW        TRUE
]]> https://forums.hyperbola.info/profile.php?id=347 2025-11-13T18:32:21Z https://forums.hyperbola.info/viewtopic.php?pid=8671#p8671 <![CDATA[Re: [Collection] Compilation of packages and ports (not in repositories)]]> Package crimson-fields

PKGBUILD

# Maintainer (Arch): Winston Weinert <winston@ml1.net>
# Maintainer: Tobias Dausend <throgh@hyperbola.info>

pkgname=crimson-fields
_pkgname=crimson
pkgver=0.5.3
pkgrel=1
pkgdesc="Free and libre turn-based tactical game with a hex grid and multiplayer support"
arch=('i686' 'x86_64')
url='http://crimson.seul.org'
license=('GPL-2')
depends=('sdl' 'sdl_ttf' 'sdl_mixer' 'sdl_net')
groups=('games')
source=("http://crimson.seul.org/files/$_pkgname-$pkgver.tar.gz")
sha512sums=('56a0c8c3e271f6ca53baaee23c28b594033b2d3e4b22fb4cd58c9858dc2bda556a13d1204cdba607da0a4414affb455b1403dde73e385a1accdd5162ec9e0a89')

build() {
  cd "$srcdir/$_pkgname-$pkgver"

  ./configure \
    --prefix=/usr \
    --bindir=/usr/games \
    --datarootdir=/usr/share/games
  make
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"

  make DESTDIR="$pkgdir/" install
  mv "$pkgdir"/usr/share/games/{applications,man,pixmaps} "$pkgdir"/usr/share
  install -Dm644 COPYING -t "$pkgdir"/usr/share/licenses/$pkgname
}
]]> https://forums.hyperbola.info/profile.php?id=347 2025-05-20T23:35:54Z https://forums.hyperbola.info/viewtopic.php?pid=8632#p8632 <![CDATA[Re: [Collection] Compilation of packages and ports (not in repositories)]]> Package heroes

PKGBUILD

# Maintainer (Arch): Steve Engledow <steve@offend.me.uk>
# Maintainer: Tobias Dausend <throgh@hyperbola.info>

pkgname=heroes
pkgver=0.21
_debver=$pkgver
_debrel=18
pkgrel=2
pkgdesc="An arena fighting game."
url='https://heroes.sourceforge.net'
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('sdl' 'sdl_mixer')
makedepends=('quilt')
groups=('games')
source=("https://downloads.sourceforge.net/heroes/$pkgname-$pkgver.tar.gz"
        "https://downloads.sourceforge.net/heroes/$pkgname-data-1.5.tar.gz"
        "https://downloads.sourceforge.net/heroes/$pkgname-sound-tracks-1.0.tar.gz"
        "https://downloads.sourceforge.net/heroes/$pkgname-sound-effects-1.0.tar.gz"
        "https://downloads.sourceforge.net/heroes/$pkgname-hq-sound-tracks-1.0.tar.gz"
        "https://deb.debian.org/debian/pool/main/h/heroes/heroes_$_debver-$_debrel.debian.tar.xz")
sha512sums=('8a28f7c0af8f194fd3557293dd65d555f4cf40e236f776ed1ef7b75f032fa511bae750d9312ba62d183129f8a529c515178ecd40f719c85583c519d531191d30'
            'ec001cda314b43b4e98f784e86bfd29da1cbac75ae981cf9ba738de0e366b47a112a21f0382a8c02737968d295f292e42451250ff9fdaee068662d0f221821f1'
            'eefa299a12b9d0a72eb73b978eab3cce5a6bcafb28acf52981762b64b7d74b7128c8a7e8517b6dcbb5281be0481c4d2fdd01de8706aefe08263ba5de4f29efae'
            '7ac2d0353122839a1b3266c6bb91c8279beade9d41f87031e4116c0a27fc7979d7a8d64fe1eab77b39a4da5869179f0ce7b8a137134df70159d745b7a63156cf'
            '565229fb00ac06d1a3ea37335138ffe87564317eab4d96b069ecd70e276f92141d9c746bc0b2d2f0abdd47e60ca580e063a2cb265d068624b4f306ce9c37f7fc'
            'c558bf06f76e5e9c74f86d14ec36d351395b2b69de7eb5c4c3bc3e18e3911585f9eca7a0f46e6b6076dafe4abca972302eeb6f4173853bd5e946eb0785eea98e')

prepare() {
  cd "$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$pkgname-$pkgver"
  LDFLAGS=-lm ./configure \
    --prefix=/usr \
    --bin=/usr/games \
    --datadir=/usr/share/games
  make

  cd "$srcdir/$pkgname-data-1.5"
  ./configure \
    --prefix=/usr \
    --datadir=/usr/share/games
  make

  cd "$srcdir/$pkgname-sound-tracks-1.0"
  ./configure \
    --prefix=/usr \
    --datadir=/usr/share/games
  make

  cd "$srcdir/$pkgname-sound-effects-1.0"
  ./configure \
    --prefix=/usr \
    --datadir=/usr/share/games
  make

  cd "$srcdir/$pkgname-hq-sound-tracks-1.0"
  ./configure \
    --prefix=/usr \
    --datadir=/usr/share/games
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir/" install
  mv "$pkgdir/"usr/share/games/locale "$pkgdir/"usr/share
  install -Dm644 debian/$pkgname.desktop "$pkgdir"/usr/share/applications/$pkgname.desktop
  install -Dm644 debian/$pkgname.xpm "$pkgdir"/usr/share/pixmaps/$pkgname.xpm
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"

  cd "$srcdir/$pkgname-data-1.5"
  make DESTDIR="$pkgdir/" install

  cd "$srcdir/$pkgname-sound-tracks-1.0"
  make DESTDIR="$pkgdir/" install

  cd "$srcdir/$pkgname-sound-effects-1.0"
  make DESTDIR="$pkgdir/" install

  cd "$srcdir/$pkgname-hq-sound-tracks-1.0"
  make DESTDIR="$pkgdir/" install
}
]]> https://forums.hyperbola.info/profile.php?id=347 2025-05-20T23:35:05Z https://forums.hyperbola.info/viewtopic.php?pid=8631#p8631 <![CDATA[Re: [Collection] Compilation of packages and ports (not in repositories)]]> Package dustrac

PKGBUILD

# Maintainer (Arch): Frederic Bezies <fredbezies at gmail dot com>
# Contributor (Arch): Daniel Milde
# Maintainer: Jayvee Enaguas <harvettfox96@dismail.de>
# Contributor: Tobias Dausend <throgh@hyperbola.info>

pkgname=dustrac
_pkgname=DustRacing2D
pkgver=2.1.1
pkgrel=2
_debver=2.1.1
_debrel=1
pkgdesc='Dust Racing 2D is a traditional top-down car racing game including a level editor'
arch=('x86_64' 'i686')
url='https://juzzlin.github.io/DustRacing2D/'
license=('GPL-3' 'CC-BY-SA-3.0')
depends=('qt-tools' 'openal' 'libvorbis' 'glu')
makedepends=('cmake' 'quilt')
groups=('games')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/juzzlin/${_pkgname}/archive/${pkgver}.tar.gz"
    "https://deb.debian.org/debian/pool/main/d/${pkgname}/${pkgname}_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('9a49cd0302ab47b12ee587a33cc74c1df2bf6cf7925141cbf957fc90a5c1a34423d4420be28bcb6909a862daa12d6214b397fd0fc77e9e18fa649f3ca5c2e1ab'
        '8824ae4dd0d281d945521262eb0a88927539ee335f475f3f42b5876bece2af32eaa1e4651b0be40d07cfd282a851c4a508229c90c23e02b40e5d3a7377399f57')

prepare() {
  cd ${_pkgname}-${pkgver}/

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian/ ./

    quilt push -av
  fi
}

build() {
  cd ${_pkgname}-${pkgver}/

  mkdir build && cd build
  cmake ../ \
    -DReleaseBuild=ON \
    -DCMAKE_INSTALL_PREFIX=/usr/ \
    -DBIN_PATH=games
  make
}

package() {
  cd ${_pkgname}-${pkgver}/build/

  make DESTDIR=${pkgdir} install
  # Install licence file.
  install -Dm644 ../COPYING -t ${pkgdir}/usr/share/licenses/${pkgname}/
}
]]> https://forums.hyperbola.info/profile.php?id=347 2025-05-20T23:34:21Z https://forums.hyperbola.info/viewtopic.php?pid=8630#p8630 <![CDATA[Re: [Collection] Compilation of packages and ports (not in repositories)]]> Package sdl3

PKGBUILD

# Maintainer (Arch): Sven-Hendrik Haase <svenstaro@archlinux.org>
# Maintainer: Tobias Dausend <throgh@hyperbola.info>

pkgname=sdl3
pkgver=3.2.14
pkgrel=1
pkgdesc="A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (Version 3)"
arch=('i686' 'x86_64')
url="https://www.libsdl.org"
license=('zlib')
depends=('glibc' 'libxext' 'libxrender' 'libx11' 'mesa-libgl' 'libxcursor' 'libusb')
makedepends=('cmake' 'ninja' 'jack' 'alsa-lib' 'mesa' 'libxrandr' 'libxinerama' 'libxkbcommon'
             'libxss' 'sndio')
optdepends=(
  'alsa-lib: ALSA audio driver'
  'sndio: sndio audio driver'
)
source=("https://github.com/libsdl-org/SDL/releases/download/release-${pkgver}/SDL3-${pkgver}.tar.gz")
sha512sums=('7e501bda73cc7b42b860e6ba6f9a0450fdb5014f5999afa64ccd6b4eb633edf6646fd1e251d58189649755a883d7dd51e5bcc53e841974180ed73d56fb8e29cd')

build() {
  CFLAGS+=" -ffat-lto-objects"
  cmake -S SDL3-${pkgver} \
    -B build -G Ninja \
    -D CMAKE_BUILD_TYPE=None \
    -D CMAKE_INSTALL_PREFIX=/usr \
    -D SDL_STATIC=OFF \
    -D SDL_RPATH=OFF
  cmake --build build
}

package() {
  DESTDIR="${pkgdir}" cmake --install build
  install -Dm644 SDL3-${pkgver}/LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
]]> https://forums.hyperbola.info/profile.php?id=347 2025-05-19T22:39:03Z https://forums.hyperbola.info/viewtopic.php?pid=8629#p8629