HyperForum — [Collection] Compilation of packages and ports (not in repositories)

Re: [Collection] Compilation of packages and ports (not in repositories)

null@example.com (throgh) — Thu, 13 Nov 2025 18:32:21 +0000

aloniv wrote:

I noticed that no NZB usenet downloader was available in Hyperbola and I remembered using NZBGet in the past.

The PKGBUILD needed is based on the official Arch one - one just needs to disable openssl, remove the systemd path and rename unrar to unar:

PKGBUILD

# Maintainer: Jaroslav Lichtblau 
# Maintainer: Carl Smedstad 
# Contributor: Alexander Rødseth 

pkgname=nzbget
pkgver=25.4
pkgrel=2
pkgdesc="Efficient usenet downloader"
arch=('x86_64')
url="https://nzbget.com"
license=('GPL-2.0-or-later')
depends=(
  'boost-libs'
  'gcc-libs'
  'glibc'
  'libxml2'
  'ncurses'
  'zlib'
)
makedepends=(
  'boost'
  'cmake'
  'git'
)
optdepends=(
  'python: to run included scripts'
  'unar: unpacking archives'
  '7zip: unpacking archives'
)
source=(
  "https://github.com/nzbgetcom/nzbget/archive/v$pkgver/$pkgname-$pkgver.tar.gz"
  "git+https://github.com/nzbgetcom/par2cmdline-turbo.git"
  "$pkgname-use-par2cmdline-turbo-from-sources.patch"
)
sha256sums=('2603116ffaef4992621cf7a82ce300f41a676a312de784f2bac5058abc1a2385'
            'SKIP'
            '9608a7166969593fea35c2db61a788a0c0083dece1907fcc33c978c70226ff0a')

prepare() {
  cd $pkgname-$pkgver
  patch -Np1 < ../$pkgname-use-par2cmdline-turbo-from-sources.patch
}

build() {
  cd $pkgname-$pkgver
  cmake -S . -B build \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -Wno-dev \
    -DENABLE_TESTS=ON \
    -DDISABLE_TLS=ON
  cmake --build build
}

check() {
  cd $pkgname-$pkgver
  ctest --test-dir build --output-on-failure
}

package() {
  cd $pkgname-$pkgver
  DESTDIR="$pkgdir" cmake --install build
  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" ./*.md
}

nzbget-use-par2cmdline-turbo-from-sources.patch

diff --unified --recursive --text --new-file nzbget-25.3.orig/cmake/par2-turbo.cmake nzbget-25.3/cmake/par2-turbo.cmake
--- nzbget-25.3.orig/cmake/par2-turbo.cmake    2025-09-01 20:50:58.443363400 +0200
+++ nzbget-25.3/cmake/par2-turbo.cmake    2025-09-01 20:51:31.722598503 +0200
@@ -51,7 +51,7 @@
 ExternalProject_add(
     par2-turbo
     PREFIX            par2-turbo
-    GIT_REPOSITORY    https://github.com/nzbgetcom/par2cmdline-turbo.git
+    GIT_REPOSITORY    file://${CMAKE_SOURCE_DIR}/../par2cmdline-turbo
     GIT_TAG            v1.3.0-20250808
     TLS_VERIFY        TRUE
     GIT_SHALLOW        TRUE

Re: [Collection] Compilation of packages and ports (not in repositories)

null@example.com (throgh) — Tue, 20 May 2025 23:35:54 +0000

Package crimson-fields

PKGBUILD

# Maintainer (Arch): Winston Weinert 
# Maintainer: Tobias Dausend 

pkgname=crimson-fields
_pkgname=crimson
pkgver=0.5.3
pkgrel=1
pkgdesc="Free and libre turn-based tactical game with a hex grid and multiplayer support"
arch=('i686' 'x86_64')
url='http://crimson.seul.org'
license=('GPL-2')
depends=('sdl' 'sdl_ttf' 'sdl_mixer' 'sdl_net')
groups=('games')
source=("http://crimson.seul.org/files/$_pkgname-$pkgver.tar.gz")
sha512sums=('56a0c8c3e271f6ca53baaee23c28b594033b2d3e4b22fb4cd58c9858dc2bda556a13d1204cdba607da0a4414affb455b1403dde73e385a1accdd5162ec9e0a89')

build() {
  cd "$srcdir/$_pkgname-$pkgver"

  ./configure \
    --prefix=/usr \
    --bindir=/usr/games \
    --datarootdir=/usr/share/games
  make
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"

  make DESTDIR="$pkgdir/" install
  mv "$pkgdir"/usr/share/games/{applications,man,pixmaps} "$pkgdir"/usr/share
  install -Dm644 COPYING -t "$pkgdir"/usr/share/licenses/$pkgname
}

Re: [Collection] Compilation of packages and ports (not in repositories)

null@example.com (throgh) — Tue, 20 May 2025 23:35:05 +0000

Package heroes

PKGBUILD

# Maintainer (Arch): Steve Engledow 
# Maintainer: Tobias Dausend 

pkgname=heroes
pkgver=0.21
_debver=$pkgver
_debrel=18
pkgrel=2
pkgdesc="An arena fighting game."
url='https://heroes.sourceforge.net'
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('sdl' 'sdl_mixer')
makedepends=('quilt')
groups=('games')
source=("https://downloads.sourceforge.net/heroes/$pkgname-$pkgver.tar.gz"
        "https://downloads.sourceforge.net/heroes/$pkgname-data-1.5.tar.gz"
        "https://downloads.sourceforge.net/heroes/$pkgname-sound-tracks-1.0.tar.gz"
        "https://downloads.sourceforge.net/heroes/$pkgname-sound-effects-1.0.tar.gz"
        "https://downloads.sourceforge.net/heroes/$pkgname-hq-sound-tracks-1.0.tar.gz"
        "https://deb.debian.org/debian/pool/main/h/heroes/heroes_$_debver-$_debrel.debian.tar.xz")
sha512sums=('8a28f7c0af8f194fd3557293dd65d555f4cf40e236f776ed1ef7b75f032fa511bae750d9312ba62d183129f8a529c515178ecd40f719c85583c519d531191d30'
            'ec001cda314b43b4e98f784e86bfd29da1cbac75ae981cf9ba738de0e366b47a112a21f0382a8c02737968d295f292e42451250ff9fdaee068662d0f221821f1'
            'eefa299a12b9d0a72eb73b978eab3cce5a6bcafb28acf52981762b64b7d74b7128c8a7e8517b6dcbb5281be0481c4d2fdd01de8706aefe08263ba5de4f29efae'
            '7ac2d0353122839a1b3266c6bb91c8279beade9d41f87031e4116c0a27fc7979d7a8d64fe1eab77b39a4da5869179f0ce7b8a137134df70159d745b7a63156cf'
            '565229fb00ac06d1a3ea37335138ffe87564317eab4d96b069ecd70e276f92141d9c746bc0b2d2f0abdd47e60ca580e063a2cb265d068624b4f306ce9c37f7fc'
            'c558bf06f76e5e9c74f86d14ec36d351395b2b69de7eb5c4c3bc3e18e3911585f9eca7a0f46e6b6076dafe4abca972302eeb6f4173853bd5e946eb0785eea98e')

prepare() {
  cd "$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$pkgname-$pkgver"
  LDFLAGS=-lm ./configure \
    --prefix=/usr \
    --bin=/usr/games \
    --datadir=/usr/share/games
  make

  cd "$srcdir/$pkgname-data-1.5"
  ./configure \
    --prefix=/usr \
    --datadir=/usr/share/games
  make

  cd "$srcdir/$pkgname-sound-tracks-1.0"
  ./configure \
    --prefix=/usr \
    --datadir=/usr/share/games
  make

  cd "$srcdir/$pkgname-sound-effects-1.0"
  ./configure \
    --prefix=/usr \
    --datadir=/usr/share/games
  make

  cd "$srcdir/$pkgname-hq-sound-tracks-1.0"
  ./configure \
    --prefix=/usr \
    --datadir=/usr/share/games
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir/" install
  mv "$pkgdir/"usr/share/games/locale "$pkgdir/"usr/share
  install -Dm644 debian/$pkgname.desktop "$pkgdir"/usr/share/applications/$pkgname.desktop
  install -Dm644 debian/$pkgname.xpm "$pkgdir"/usr/share/pixmaps/$pkgname.xpm
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"

  cd "$srcdir/$pkgname-data-1.5"
  make DESTDIR="$pkgdir/" install

  cd "$srcdir/$pkgname-sound-tracks-1.0"
  make DESTDIR="$pkgdir/" install

  cd "$srcdir/$pkgname-sound-effects-1.0"
  make DESTDIR="$pkgdir/" install

  cd "$srcdir/$pkgname-hq-sound-tracks-1.0"
  make DESTDIR="$pkgdir/" install
}

Re: [Collection] Compilation of packages and ports (not in repositories)

null@example.com (throgh) — Tue, 20 May 2025 23:34:21 +0000

Package dustrac

PKGBUILD

# Maintainer (Arch): Frederic Bezies 
# Contributor (Arch): Daniel Milde
# Maintainer: Jayvee Enaguas 
# Contributor: Tobias Dausend 

pkgname=dustrac
_pkgname=DustRacing2D
pkgver=2.1.1
pkgrel=2
_debver=2.1.1
_debrel=1
pkgdesc='Dust Racing 2D is a traditional top-down car racing game including a level editor'
arch=('x86_64' 'i686')
url='https://juzzlin.github.io/DustRacing2D/'
license=('GPL-3' 'CC-BY-SA-3.0')
depends=('qt-tools' 'openal' 'libvorbis' 'glu')
makedepends=('cmake' 'quilt')
groups=('games')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/juzzlin/${_pkgname}/archive/${pkgver}.tar.gz"
    "https://deb.debian.org/debian/pool/main/d/${pkgname}/${pkgname}_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('9a49cd0302ab47b12ee587a33cc74c1df2bf6cf7925141cbf957fc90a5c1a34423d4420be28bcb6909a862daa12d6214b397fd0fc77e9e18fa649f3ca5c2e1ab'
        '8824ae4dd0d281d945521262eb0a88927539ee335f475f3f42b5876bece2af32eaa1e4651b0be40d07cfd282a851c4a508229c90c23e02b40e5d3a7377399f57')

prepare() {
  cd ${_pkgname}-${pkgver}/

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian/ ./

    quilt push -av
  fi
}

build() {
  cd ${_pkgname}-${pkgver}/

  mkdir build && cd build
  cmake ../ \
    -DReleaseBuild=ON \
    -DCMAKE_INSTALL_PREFIX=/usr/ \
    -DBIN_PATH=games
  make
}

package() {
  cd ${_pkgname}-${pkgver}/build/

  make DESTDIR=${pkgdir} install
  # Install licence file.
  install -Dm644 ../COPYING -t ${pkgdir}/usr/share/licenses/${pkgname}/
}

Re: [Collection] Compilation of packages and ports (not in repositories)

null@example.com (throgh) — Mon, 19 May 2025 22:39:03 +0000

Package sdl3

PKGBUILD

# Maintainer (Arch): Sven-Hendrik Haase 
# Maintainer: Tobias Dausend 

pkgname=sdl3
pkgver=3.2.14
pkgrel=1
pkgdesc="A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (Version 3)"
arch=('i686' 'x86_64')
url="https://www.libsdl.org"
license=('zlib')
depends=('glibc' 'libxext' 'libxrender' 'libx11' 'mesa-libgl' 'libxcursor' 'libusb')
makedepends=('cmake' 'ninja' 'jack' 'alsa-lib' 'mesa' 'libxrandr' 'libxinerama' 'libxkbcommon'
             'libxss' 'sndio')
optdepends=(
  'alsa-lib: ALSA audio driver'
  'sndio: sndio audio driver'
)
source=("https://github.com/libsdl-org/SDL/releases/download/release-${pkgver}/SDL3-${pkgver}.tar.gz")
sha512sums=('7e501bda73cc7b42b860e6ba6f9a0450fdb5014f5999afa64ccd6b4eb633edf6646fd1e251d58189649755a883d7dd51e5bcc53e841974180ed73d56fb8e29cd')

build() {
  CFLAGS+=" -ffat-lto-objects"
  cmake -S SDL3-${pkgver} \
    -B build -G Ninja \
    -D CMAKE_BUILD_TYPE=None \
    -D CMAKE_INSTALL_PREFIX=/usr \
    -D SDL_STATIC=OFF \
    -D SDL_RPATH=OFF
  cmake --build build
}

package() {
  DESTDIR="${pkgdir}" cmake --install build
  install -Dm644 SDL3-${pkgver}/LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

Re: [Collection] Compilation of packages and ports (not in repositories)

null@example.com (throgh) — Mon, 19 May 2025 22:14:30 +0000

Package scappit

PKGBUILD

# Maintainer (Arch): Oliver Giles 
# Maintainer: Tobias Dausend 

pkgname=scappit
pkgver=0.3
pkgrel=1
pkgdesc="Simple screen capture and annotation"
arch=('i686' 'x86_64')
url='https://scappit.ohwg.net'
license=('Expat')
depends=('qt-base' 'qt-x11extras' 'gnome-icon-theme')
makedepends=('cmake')
options=('strip')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/ohwgiles/$pkgname/archive/v${pkgver}.tar.gz"
        "${pkgname}.desktop")
sha512sums=('66eac8dbd1f259ac92403029cd3558605d00f61c57846cce547ece503a9e9f691d98dafa50eab256448b762ac763c78886e0fa1ad6de331521de390f811994cf'
            '41364792a000f6065c85c60422a5c68c56951063be11a2d65ce25a7e38469b1c8e165e0de1fb766e978a6af124a9fd272c39e7303731bdecb3046be53e639ed1')

build() {
  cmake \
    -S $pkgname-$pkgver \
    -B build \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -Wno-dev
  make -C build
}

package() {
  make DESTDIR="$pkgdir/" -C build install/strip
  install -Dm644 "$srcdir/$pkgname.desktop" -t "$pkgdir/usr/share/applications"
  install -Dm644 "$srcdir/$pkgname-$pkgver/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname"
}

scappit.desktop

[Desktop Entry]
Version=1.0
Name=Scappit
GenericName=Simple screen capture and annotation
Comment=Simple screen capture and annotation
Type=Application
Categories=Graphics;GTK;
Exec=scappit
TryExec=scappit
Terminal=false
StartupNotify=true
Icon=applets-screenshooter

Re: [Collection] Compilation of packages and ports (not in repositories)

null@example.com (throgh) — Tue, 15 Apr 2025 22:01:22 +0000

Package rmw

PKGBUILD

# Maintainer (Arch): Andy Alt 
# Contributor (Arch): Oliver Jaksch 
# Maintainer: Tobias Dausend 

pkgname=rmw
pkgver=0.8.0
pkgrel=1
pkgdesc="Trash/recycle bin utility for the commandline"
arch=('i686' 'x86_64')
url='https://theimpossibleastronaut.com/rmw-website/'
license=('GPL-3')
depends=('glibc' 'ncurses')
makedepends=('meson' 'ninja')
source=("https://github.com/theimpossibleastronaut/rmw/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha512sums=('5744e4b46edecfd6d0588d9b0ecbc8a91e8495f2e07d87599d045f620a2ae08381e9efa97cfa51c83cfcf8a2e89a594f8e87c374dc452ffb5b1bd2371b46aa22')

build() {
  hyperbola-meson $pkgname-$pkgver build -Db_sanitize=none
  meson compile -v -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
  rm -rf "$pkgdir/usr/share/doc/$pkgname/external"
  install -Dm644 "$srcdir/$pkgname-$pkgver/COPYING" -t "$pkgdir/usr/share/licenses/$pkgname"
}

Re: [Collection] Compilation of packages and ports (not in repositories)

null@example.com (throgh) — Sun, 13 Apr 2025 19:52:10 +0000

Package cdrip-tools

PKGBUILD

# Maintainer (Arch): John Lane 
# Maintainer: Tobias Dausend 

pkgname=cdrip-tools
pkgver=0.3
pkgrel=1
pkgdesc="Commandline accuraterip verifier and rip offset fixer"
url='https://github.com/spadev/cdrip-tools'
arch=('i686' 'x86_64')
license=('GPL-3')
depends=('python' 'libsndfile')
source=("${pkgname}-${pkgver}.zip::https://github.com/spadev/${pkgname}/archive/master.zip")
sha512sums=('43493a2f7b0f8cd0fc9f3de82cc3d1f0bb81b770e468ba7bf3259c89cbd7de3d1ba1295d1f628cf3dc7d65ab8fbc4cca7d73b85309932dd81eb0369d9137c20a')

prepare() {
  mv "$pkgname-master" "$pkgname-$pkgver"
}

build() {
  cd $srcdir/$pkgname-$pkgver
  cc -o ckcdda ckcdda.c
  cc -o splitaudio -l sndfile splitaudio.c

  # nasty library hack - change name to something less generic
  sed -i -e 's/^import utils/import cdrip_utils as utils/' \
         -e 's/^from utils/from cdrip_utils/' *.py
}

package() {
  cd $srcdir/$pkgname-$pkgver
  install -Dm644 README.md $pkgdir/usr/share/doc/$pkgname/README.md
  install -Dm755 arverify.py $pkgdir/usr/bin/arverify
  install -Dm755 fixoffset.py $pkgdir/usr/bin/fixoffset
  install -Dm755 splitaudio $pkgdir/usr/bin/
  install -Dm755 ckcdda $pkgdir/usr/bin/

  # nasty library hack - install renamed library (hopefully in site-packages!)
  pylibdir=$(python -c "import sys; print(sys.path[-1]);")
  install -Dm755 utils.py $pkgdir${pylibdir}/cdrip_utils.py

  install -Dm644 LICENSE -t $pkgdir/usr/share/licenses/$pkgname
}

Re: [Collection] Compilation of packages and ports (not in repositories)

null@example.com (throgh) — Mon, 03 Mar 2025 23:12:51 +0000

Package fricas

PKGBUILD

# Maintainer (Arch): Antonio Rojas 
# Contributor (Arch): Sergey Khorev 
# Maintainer: Tobias Dausend 

pkgname=fricas
pkgver=1.3.8
_debver=$pkgver
_debrel=6
pkgrel=1
pkgdesc="An advanced computer algebra system"
arch=('i686' 'x86_64')
url='https://fricas.github.io'
license=('Modified-BSD')
depends=('gawk' 'glibc' 'libx11' 'libxpm' 'sh')
makedepends=('sbcl-legacy' 'quilt')
options=(!strip)
source=("$pkgname-$pkgver.tar.bz2::https://deb.debian.org/debian/pool/main/f/fricas/fricas_$pkgver.orig.tar.bz2"
        "https://deb.debian.org/debian/pool/main/f/fricas/fricas_$_debver-$_debrel.debian.tar.xz")
sha512sums=('330554f9dc36b47451195e3dee88fe26a80ab2bf9b6750d651cd53c5ba16b9c9736176936c7c69e699685be25aa62b6a099ed7340913e946a4f5e53579835dbb'
            '6f34cb205fb13f7018a5c1bf4d278f1fe331e5de41f713180cb953a36bf75455fc55308c3a39d2e4104f4d8f167dcdff8f7012b6d13f22abe3511013161d58c8')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/package-names-and-ansi-pathname || true

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --with-lisp='sbcl \
    --control-stack-size 512 \
    --dynamic-space-size 6000'
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 license/LICENSE.AXIOM -t "$pkgdir"/usr/share/licenses/$pkgname
}

Re: [Collection] Compilation of packages and ports (not in repositories)

null@example.com (throgh) — Sun, 12 Jan 2025 19:08:32 +0000

Package pekwm-themes

PKGBUILD

# Maintainer (Arch): Alexander F Rødseth 
# Maintainer: Tobias Dausend 

pkgname=pekwm-themes
pkgver=1.0.5
_debver=$pkgver
_debrel=7
pkgrel=1
pkgdesc="PekWM theme collection"
arch=('any')
license=('GPL-2' 'GPL-3')
depends=('pekwm')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/p/pekwm-themes/pekwm-themes_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/pekwm-themes/pekwm-themes_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('94ef6e1cb564fcc28601729e1a6e95c6f858ab7a31ea9bf3ad8478398931229ee0087ec3724c4df263b45191064503dae91bee7e8abeeeca10ca783601ad2fe3'
            '310df602fa223650cde9a7cbf6f8f46619d5ae4ef9ae241552ac629c9a619eb3b17b80e2109a6baf4c4638a65c7aa8e8916c5523e439f91f8d39aea1cbef0555')

package() {
  install -d "$pkgdir/usr/share/pekwm/themes"
  cp -R "$srcdir/$pkgname/"* "$pkgdir/usr/share/pekwm/themes/"
  install -Dm644 "$srcdir/debian/copyright" -t "$pkgdir/usr/share/licenses/$pkgname"
}

Re: [Collection] Compilation of packages and ports (not in repositories)

null@example.com (throgh) — Sun, 12 Jan 2025 19:07:40 +0000

Package pekwm

PKGBUILD

# Maintainer (Arch): Alexander F. Rødseth 
# Contributor (Arch): Kevin Piche 
# Contributor (Arch): Eddie Lozon 
# Maintainer: Tobias Dausend 

pkgname=pekwm
pkgver=0.1.18
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="Tabbed X11 window manager"
arch=('i686' 'x86_64')
license=('GPL-2')
url='https://github.com/pekdon/pekwm'
depends=('libjpeg-turbo' 'libxft' 'libxinerama' 'libxpm' 'libxrandr')
makedepends=('quilt')
optdepends=('lxappearance: feature-rich GTK+ theme switcher'
            'nitrogen: background browser and setter'
            'tint2: basic, good-looking task manager')
backup=('etc/pekwm/autoproperties'
        'etc/pekwm/autoproperties_typerules'
        'etc/pekwm/config'
        'etc/pekwm/config_system'
        'etc/pekwm/keys'
        'etc/pekwm/menu'
        'etc/pekwm/mouse'
        'etc/pekwm/mouse_click'
        'etc/pekwm/mouse_sloppy'
        'etc/pekwm/mouse_system'
        'etc/pekwm/start'
        'etc/pekwm/vars')
source=("https://github.com/${pkgname}/${pkgname}/releases/download/release-${pkgver}/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/pekwm/pekwm_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('7fe04c04089d3375d1f64d456a7a582e88fd1f442c1c710bdef71309c7fe5aab234026ba381eb9a49b3d459b759924b577ba9597156e46e60147a9d845c27e89'
            '7f8d285b2725ee24b5fcefc1bacbb9b9738f58c19b49bafe40645e72f71f9ca1498a55185184f22906cbdfa404c626b8e7abc33406549af0b85ba8d36f78c615')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  ./autogen.sh
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc
  make
}

package() {
  make -C $pkgname-$pkgver DESTDIR="$pkgdir" install
  install -Dm644 "$srcdir"/$pkgname-$pkgver/debian/$pkgname.desktop "$pkgdir"/usr/share/xsessions/$pkgname.desktop
  install -Dm644 "$srcdir"/$pkgname-$pkgver/LICENSE -t "${pkgdir}/usr/share/licenses/$pkgname"
}

Re: [Collection] Compilation of packages and ports (not in repositories)

null@example.com (throgh) — Sun, 12 Jan 2025 19:06:42 +0000

Package enlightenment16

PKGBUILD

# Maintainer (Arch): Brian BIdulock 
# Contributor (Arch): Eric Bélanger 
# Maintainer: André Silva 
# Contributor: Tobias Dausend 

pkgname=enlightenment16
pkgver=1.0.29
_themever=1.0.3
pkgrel=1
pkgdesc="A fast, flexible, and very extensible Window Manager"
arch=('i686' 'x86_64')
url='https://www.enlightenment.org/e16'
license=('Expat')
depends=('libxinerama' 'imlib2' 'perl' 'pango' 'libxcomposite' 'sndio' 'libxrandr' 'libxdamage' 'libsndfile')
makedepends=('libsndio')
source=("https://downloads.sourceforge.net/sourceforge/enlightenment/e16-${pkgver}.tar.gz"
        "https://downloads.sourceforge.net/enlightenment/e16-themes-${_themever}.tar.gz"
        "starte16")
sha512sums=('e95dc2ad05b4f2ec3f374c5268f8f790e9ddd212f4e5e60d3517ade8645e539de5207553a841e14d1c099496f8385271f3f95867ef8ebfd99c419201477ef299'
            '6c8d7d15233f401c9b6c406116d822c42b7eed9b81570f2f25824886eee0a8c51895dfeeffa5c6e820f5e9449d9d28ec55e029f1136b5cb55cd7072fe9f57cba'
            '99f382ddcb0951f38e3bff686cf4e2940e408729490719108e671c4bae7aae3708f8c6222b392ebf31bef21b788f8de7bdd894402b3e060dc0c9f716f78b0c22')

build() {
  pushd e16-${pkgver}
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --enable-sound=sndio \
    --enable-dbus=no \
    --with-gnome=no
  make
  popd
  
  cd e16-themes-${_themever}
  ./configure --prefix=/usr
}

package() {
  cd e16-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -D -m644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  install -D -m644 fonts/COPYRIGHT.Vera -t "${pkgdir}/usr/share/licenses/${pkgname}"

  cd "${srcdir}/e16-themes-${_themever}"
  make DESTDIR="${pkgdir}" install
  chown -R root:root "${pkgdir}"/usr/share/*

  # removing unsupported
  rm "${pkgdir}"/usr/share/e16/misc/e16-dbus-cmd
  rm "${pkgdir}"/usr/share/e16/misc/starte16-gnome
  rm "${pkgdir}"/usr/share/e16/misc/starte16-kde
  rm "${pkgdir}"/usr/share/e16/misc/Xclients.e16-gnome.sh
  rm "${pkgdir}"/usr/share/e16/misc/Xclients.e16-kde.sh
  rm "${pkgdir}"/usr/share/xsessions/e16-kde-session.desktop

  # attach script
  rm "${pkgdir}"/usr/share/e16/misc/starte16
  cp "${srcdir}"/starte16  "${pkgdir}"/usr/share/e16/misc/
}

starte16

#!/bin/sh

s=$1
test -z "$s" && s=$0

case "$s" in
*window)
    exec /usr/bin/e16 -w ${SIZE:-800x600}
    ;;
*)
    exec /usr/bin/e16
    ;;
esac

Re: [Collection] Compilation of packages and ports (not in repositories)

null@example.com (throgh) — Fri, 10 Jan 2025 13:25:02 +0000

Package sar2 (Search and Rescue 2)

PKGBUILD

# Maintainer (Arch): Popolon 
# Maintainer: Tobias Dausend 

_name=SearchAndRescue2
pkgname=sar2
pkgver=2.5.0
pkgrel=2
pkgdesc="Free and libre helicopter simulator"
url='https://searchandrescue2.github.io/sar2/'
license=('GPL-2')
arch=('i686' 'x86_64')
depends=('freealut' 'openal' 'libvorbis' 'sdl2' 'libsm' 'libxmu' 'libxpm' 'glu')
makedepends=('scons' 'python-setuptools')
groups=('games')
source=("https://github.com/$_name/$pkgname/archive/v$pkgver.tar.gz"
        "fhs-compliant.patch")
sha512sums=('b5e6036e9ca0bce4245b951cdc16e676470f95906c714b28facf0006c4db838d86dbb57982712fa5f6abb9bd774c61b9d1c593c82b08325e9f28db25273a194a'
            '754ced777865fbd2eb4102eb79eeb8ebb6ffad3e4a0ff81c9cdf29a089d33adf779c146aaa8b25c914e6034fc52545f7d760e7e51a385b142a54f1893d2373b6')

prepare() {
  cd "$pkgname-$pkgver"
  patch -Np1 -i ${srcdir}/fhs-compliant.patch
}

build() {
  cd "$pkgname-$pkgver"
  scons
}

package() {
  cd "$pkgname-$pkgver"
  scons install --prefix=${pkgdir}/usr
  install -Dm644 extra/$pkgname.desktop "${pkgdir}/usr/share/applications/$pkgname.desktop"
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/$pkgname"
}

fhs-compliant.patch

--- a/src/SConscript    2020-06-20 23:48:35.000000000 +0200
+++ b/src/SConscript    2021-10-24 17:56:07.030471759 +0200
@@ -177,11 +177,11 @@
 """)
 
 object_list = env.Object(source = sources)
-sar2 = env.Program(target='#bin/sar2', source=[object_list])
+sar2 = env.Program(target='#games/sar2', source=[object_list])
 data='#data'
 man='#man/sar2.6.bz2'
 pixmap='#extra/sar2.xpm'
-env.Alias("install", env.InstallAs('$DESTDIR/$PREFIX/share/sar2', data))
+env.Alias("install", env.InstallAs('$DESTDIR/$PREFIX/share/games/sar2', data))
 env.Alias("install", env.Install('$DESTDIR/$PREFIX/share/man/man6', man))
 env.Alias("install", env.Install('$DESTDIR/$PREFIX/share/pixmaps', pixmap))
-env.Alias("install", env.Install('$DESTDIR/$PREFIX/bin', sar2))
+env.Alias("install", env.Install('$DESTDIR/$PREFIX/games', sar2))
--- a/src/config.h    2020-06-20 23:48:35.000000000 +0200
+++ b/src/config.h    2021-10-24 18:06:58.489853438 +0200
@@ -502,7 +502,7 @@
 #define SAR_DEF_LOCAL_DATA_DIR  ".config/sar2"
 
 /* Game data dir */
-#define SAR_DEF_GLOBAL_DATA_DIR "/usr/share/sar2"
+#define SAR_DEF_GLOBAL_DATA_DIR "/usr/share/games/sar2"
 
 /* Subdirs, one of each in the local and global game dirs */
 #define SAR_DEF_AIRCRAFTS_DIR        "aircrafts"

Re: [Collection] Compilation of packages and ports (not in repositories)

null@example.com (throgh) — Fri, 10 Jan 2025 13:23:50 +0000

Package sar (Search and Rescue)

PKGBUILD

# Maintainer: Tobias Dausend 

pkgname=sar
_pkgbase=SearchAndRescue
_pkgname=searchandrescue
pkgver=1.5.0
_debver=$pkgver
_debrel=2.1
pkgdataver=1.3.0
pkgrel=1
pkgdesc="Fly aircraft to search (for) and rescue people in distress"
url='http://sourceforge.net/projects/searchandrescue/'
license=('GPL-2')
arch=('i686' 'x86_64')
depends=('glibc' 'glu' 'sdl' 'sdl_mixer' 'libx11' 'libxpm' 'libxxf86vm' 'libxext' 'libxmu')
makedepends=('clang')
groups=('games')
source=("https://deb.debian.org/debian/pool/main/s/searchandrescue/searchandrescue_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/s/searchandrescue/searchandrescue_${_debver}-${_debrel}.diff.gz"
        "https://deb.debian.org/debian/pool/main/s/searchandrescue-data/searchandrescue-data_${pkgdataver}.orig.tar.gz")
sha512sums=('72a8e5c375bb2f5d11d1346bb3c81ea4678a9c58c36f53c048e9a16d32a926ff93c3ec9756867f0869aa2a8da5fb0bfe7764f704c4e79519ee0834d225513657'
            '7e3d76e54684f0a8f761dbbbc426a3bf68802d9a546864ef8c306b542b757976e9e73d0a9da70fba6c55a6c83d90c89b801815bd251f0462c7a463de061752cb'
            '5419376aeecb0f05570a8d2a0a6f830f3b22ce9d1d34a5e490485767546c6d0d1d2a2a3f37e5dfcef69e271a94a9c7dfc6b592e3c0dd62a8a6c38e4bf7d25ccd')
noextract=("searchandrescue-data_${pkgdataver}.orig.tar.gz")

prepare() {
  cd ${_pkgname}_${pkgver}
  patch -Np1 < ${srcdir}/${_pkgname}_${_debver}-${_debrel}.diff
}

build() {
  cd ${_pkgname}_${pkgver}
  make
}

package() {
  cd ${_pkgname}_${pkgver}
  make DESTDIR="$pkgdir/" install

  # install data-files
  install -d "${pkgdir}/usr/share/games/$_pkgname"
  tar -xzf "${srcdir}/searchandrescue-data_${pkgdataver}.orig.tar.gz" \
      -C   "${pkgdir}/usr/share/games/$_pkgname/"

  # install metadata-files
  install -Dm644 debian/$_pkgbase.desktop "${pkgdir}/usr/share/applications/"$_pkgbase.desktop

  # install license
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/$pkgname/"
}

Re: [Collection] Compilation of packages and ports (not in repositories)

null@example.com (throgh) — Fri, 10 Jan 2025 00:31:34 +0000

Package abbayedesmorts

PKGBUILD

# Maintainer: Tobias Dausend 

pkgname=abbayedesmorts
pkgver=2.0.4
pkgrel=1
pkgdesc="l'Abbaye des Morts - An obsolete, free and libre video game for a dark passage of history"
arch=('i686' 'x86_64')
url='https://github.com/nevat/abbayedesmorts-gpl'
license=('GPL-3' 'CC-BY-3.0')
depends=('sdl2' 'sdl2_image' 'sdl2_mixer')
groups=('games')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/nevat/abbayedesmorts-gpl/archive/refs/tags/v${pkgver}.tar.gz"
        "fhs-compliant.patch")
sha512sums=('46e2384c2f176dd54c3056d2e8a7ea1ea40da918bc1598414c68a2449f198e49c3dba30dc8c3c771f8d37e7a6eaa38caccbc2275d1712b7a8e5332ca400c5562'
            '0e57c75c0887f0016c1508d980099c55ab6ae1ef2fdb9a7e1359a6f4e1fd958ec6a116d77de4dcf8436f65c66bb4dec5813488691d41880c704aa584cb97f3e6')

prepare() {
  mv "${pkgname}-gpl-${pkgver}" "${pkgname}-${pkgver}"
  cd "${pkgname}-${pkgver}"
  patch -Np1 -i "$srcdir/fhs-compliant.patch"
}

build() {
  cd "${pkgname}-${pkgver}"
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  mkdir -p "$pkgdir/usr/games"
  mkdir -p "$pkgdir/usr/share"
  mkdir -p "$pkgdir/usr/share/applications"
  mkdir -p "$pkgdir/usr/share/pixmaps"
  make DESTDIR="$pkgdir" install

  # license
  install -Dm644 {COPYING,ReadMe.md} -t "$pkgdir/usr/share/licenses/$pkgname"
}

fhs-compliant.patch

--- a/Makefile    2024-09-23 23:18:05.000000000 +0200
+++ b/Makefile    2024-12-15 02:36:43.892348396 +0100
@@ -23,7 +23,7 @@
 DATADIR= "\"./\""
 endif
 
-DATADIR?="\"$(PREFIX)/share/abbayev2\""
+DATADIR?="\"$(PREFIX)/share/games/abbayev2\""
 LDFLAGS?=    -Wl,-z,relro
 
 CFLAGS+=    `sdl2-config --cflags` -DDATADIR=$(DATADIR)
@@ -61,28 +61,28 @@
 
 # Installation
 install: $(PROG)
-    mkdir -p $(DESTDIR)$(PREFIX)/bin
-    cp $(PROG) $(DESTDIR)$(PREFIX)/bin
+    mkdir -p $(DESTDIR)$(PREFIX)/games
+    cp $(PROG) $(DESTDIR)$(PREFIX)/games
     mkdir -p $(DESTDIR)$(PREFIX)/share/applications
     cp abbaye.desktop $(DESTDIR)$(PREFIX)/share/applications
-    mkdir -p $(DESTDIR)$(PREFIX)/share/abbayev2/sounds
-    cp ./sounds/* $(DESTDIR)$(PREFIX)/share/abbayev2/sounds
-    mkdir -p $(DESTDIR)$(PREFIX)/share/abbayev2/data
-    cp ./data/* $(DESTDIR)$(PREFIX)/share/abbayev2/data
+    mkdir -p $(DESTDIR)$(PREFIX)/share/games/abbayev2/sounds
+    cp ./sounds/* $(DESTDIR)$(PREFIX)/share/games/abbayev2/sounds
+    mkdir -p $(DESTDIR)$(PREFIX)/share/games/abbayev2/data
+    cp ./data/* $(DESTDIR)$(PREFIX)/share/games/abbayev2/data
     mkdir -p $(DESTDIR)$(PREFIX)/share/pixmaps
     cp abbaye.png $(DESTDIR)$(PREFIX)/share/pixmaps
-    mkdir -p $(DESTDIR)$(PREFIX)/share/abbayev2/graphics
-    cp -r ./graphics/* $(DESTDIR)$(PREFIX)/share/abbayev2/graphics
+    mkdir -p $(DESTDIR)$(PREFIX)/share/games/abbayev2/graphics
+    cp -r ./graphics/* $(DESTDIR)$(PREFIX)/share/games/abbayev2/graphics
     mkdir -p $(DESTDIR)$(PREFIX)/share/appdata
     cp ./appdata/abbaye.appdata.xml $(DESTDIR)$(PREFIX)/share/appdata
 
 uninstall:
-    rm $(DESTDIR)$(PREFIX)/bin/$(PROG)
+    rm $(DESTDIR)$(PREFIX)/games/$(PROG)
     rm $(DESTDIR)$(PREFIX)/share/applications/abbaye.desktop
     rm $(DESTDIR)$(PREFIX)/share/pixmaps/abbaye.png
-    rm -rf $(DESTDIR)$(PREFIX)/share/abbayev2
+    rm -rf $(DESTDIR)$(PREFIX)/share/games/abbayev2
     rm $(DESTDIR)$(PREFIX)/share/appdata/abbaye.appdata.xml
     # ignore if not empty
-    -rmdir $(DESTDIR)$(PREFIX)/bin
+    -rmdir $(DESTDIR)$(PREFIX)/games
     -rmdir $(DESTDIR)$(PREFIX)/share/applications
     -rmdir $(DESTDIR)$(PREFIX)/share/pixmaps