# Maintainer (Arch): MCMic <come@chilliet.eu>
# Contributor (Arch): MCMic <come@chilliet.eu>
# Contributor (Arch): Sam101 <zoetrem @t gmail dot com>
# Contributor (Arch): BenObiWan <benobiwan @t gmail dot com>
# Contributor (Arch): Huulivoide
# Contributor (Arch): Fernando Carmona Varo <ferkiwi @t gmail dot com>
# Contributor (Arch): Franck Stauffer <franck.stauffer@monaco.mc>
# Maintainer: Tobias Dausend <throgh@hyperbola.info>

pkgname=solarus
pkgver=1.6.5
pkgrel=1
pkgdesc="A lightweight, free and libre game engine for Action-RPGs"
arch=('i686' 'x86_64')
url='https://www.solarus-games.org/'
license=('GPL-3' 'CC-BY-SA-3.0' 'CC-BY-SA-4.0')
depends=('glm' 'hicolor-icon-theme' 'libmodplug' 'libvorbis'
         'luajit' 'openal' 'physfs' 'qt-base'
         'qt-tools' 'sdl2' 'sdl2_image' 'sdl2_ttf')
makedepends=('cmake')
groups=('games')
source=("https://gitlab.com/solarus-games/${pkgname}/-/archive/v${pkgver}/${pkgname}-v${pkgver}.tar.gz")
sha512sums=('3fc7473f1b7dd80cbcb0a7a639701f8b12bd40ee918a7853805bd54f877e752b4c31c26828e62248ca4594b3aed41a8c61a16be3b14b293f08d9ba938a723e91')

prepare() {
  cmake \
    -Wno-dev \
    -B build \
    -S "$pkgname-v$pkgver" \
    -DSOLARUS_TESTS=OFF \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    -DCMAKE_INSTALL_BINDIR="games" \
    -DCMAKE_INSTALL_DATADIR="share/games" \
    -DCMAKE_BUILD_TYPE=Release
}

build() {
  make -C build ${MAKEFLAGS}
}

package() {
  make -C build DESTDIR="${pkgdir}/" install
  mv "${pkgdir}/usr/share/games/"{icons,pixmaps,applications,metainfo} "${pkgdir}/usr/share/"
  install -Dm644 "${srcdir}/$pkgname-v$pkgver/"license{,_gpl}.txt -t "${pkgdir}/usr/share/licenses/$pkgname"
}

# Maintainer: Morten Linderud <foxboron@archlinux.org>
# Contributor: Tilman BLUMENBACH <tilman+aur AT ax86 DOT net>

pkgname=(barrier barrier-headless)
pkgver=2.4.0
pkgrel=2
pkgdesc="Open-source KVM software based on Synergy"
arch=(x86_64)
url="https://github.com/debauchee/barrier"
license=("custom:GPL2WithOpenSSLException")
changelog=CHANGELOG.rst
depends=(curl libx11 libxrandr libxext
        libxinerama xorgproto libxtst libxi
        libsm libice openssl)
makedepends=(cmake git qt5-base hicolor-icon-theme)
source=("git+https://github.com/debauchee/barrier.git#tag=v${pkgver}")
sha256sums=('SKIP')

prepare() {
    cd "barrier"
    git submodule update --init --recursive
    # lib/platform: Fix encoding for text copied between linux and windows
    # https://github.com/debauchee/barrier/commit/dd3ea8adfef868e52098ea24d2ed08320a90e3b9
    git cherry-pick -n dd3ea8adfef868e52098ea24d2ed08320a90e3b9

    # Add missing cstddef includes for NULL
    # https://github.com/debauchee/barrier/commit/4b12265ae5d324b942698a3177e1d8b1749414d7
    git cherry-pick -n 4b12265ae5d324b942698a3177e1d8b1749414d7
}

build() {
    cd "barrier"

    mkdir -p build
    cd build

    cmake -G "Unix Makefiles" \
        -D CMAKE_BUILD_TYPE:STRING=Release \
        -D CMAKE_INSTALL_PREFIX:STRING=/usr \
        -D BARRIER_REVISION:STRING=00000000 \
        -D BARRIER_VERSION_STAGE:STRING=RELEASE \
        -D AVAHI_COMPAT_NOWARN:bool=true \
        -D BARRIER_BUILD_GUI:bool=false \
        ..
    make
}


_package_common() {
    # Install binaries:
    cd "barrier/build"
    DESTDIR="${pkgdir}" make install

    # Install the license:
    cd ..
    install -m 644 -D LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

    # Install the manpages:
    mkdir -p "${pkgdir}/usr/share/man/man1"
    install -m 644 doc/*.1 "${pkgdir}/usr/share/man/man1"

    # Install the examples:
    mkdir -p "${pkgdir}/usr/share/doc/${pkgname}"
    install -m 644 doc/barrier.conf* "${pkgdir}/usr/share/doc/${pkgname}"
}

package_barrier() {
    pkgdesc="Open-source KVM software based on Synergy (GUI)"
    depends=("barrier-headless=${pkgver}-${pkgrel}" qt5-base hicolor-icon-theme)

    # Install all the files:
    _package_common

    # Now go and delete files that are already in
    # barrier-headless:
    for file in \
        /usr/share/doc \
        /usr/share/man \
        /usr/bin/barrier{s,c} \
    ;do
        rm -rf "${pkgdir}/${file}"
    done
}

package_barrier-headless() {
    pkgdesc="Open-source KVM software based on Synergy (client and server CLI binaries)"

    # Install all the files:
    _package_common

    # Now go and delete the GUI-related files:
    for file in \
        /usr/bin/barrier \
        /usr/share/applications \
        /usr/share/icons \
    ;do
        rm -rf "${pkgdir}/${file}"
    done
}