Hello berni, welcome to the forums. About the missing packages in general: It depends on their stand. For "joe": If there is a BSD-port available we can look out for adding it as Hyperbola is transitioning main towards BSD on its own.

For "xenodm" I'm not finally sure at the moment, but we have a bunch of other window-managers nevertheless available. I will clear that point and come back later with an answer for sure.

But about the "pax-tools": You have mentioned that you have used the Arch-package. Hyperbola only shares basics with Arch GNU/Linux, the rest is complete on its own as Hyperbola is using a different approach with many parts. We are for example not using zstd-compression for the packages and it seems the package you have used was built with a different version of the glibc. This can be the reasoning when you have downloaded the same package but on different dates as Arch GNU/Linux may have refreshed their version and uploaded the new build in their repositories. The conclusion would be therefore: Compiling your own pacage perhaps? If you want I can assist and help you here for sure within this thread, guiding you through the course doing that.

Okay, we will look for sure about what is possible especially when it comes to xenodm. But let's look towards pax-utils (I hope I have selected the correct one). I will list first the generic steps:

1. Enumerate the package itself throughout either Arch GNU/Linux or Debian. In that case: Arch has all fitting here.
2. Let's look into the PKGBUILD and the corresponding parts: https://github.com/archlinux/svntogit-c … tils/trunk
3. At best you download the PKGBUILD-script complete within a selected folder: https://raw.githubusercontent.com/archl … k/PKGBUILD
4. When something is missing you will also need to compile the dependencies the same way. I see there is python-pyelftools needed.

In the end: If this is the wrong package, the steps are nevertheless the same. When you have all fitting in the folder you can use the command makepkg to try a first build for the corresponding package. It is not bad if you know state for yourself this is quite too much. Being here to go step by step and this would be only a first tryout. Learning by doing as technical emancipation is one of our highest values here.

Oh sorry, than I had the wrong package, but the steps are surely the same. That is even easier as the dependencies are not much. But to clear that up: A PKGBUILD has three possible sets of dependencies:

depends means as keyword all depedencies you will surely need at runtim.
makedepends means as keyword all dependencies you will need at build-time.
optdepends means as keyword all optional dependencies.

This would the PKGBUILD you all need:

# Maintainer: Daniel Bermond <dbermond@archlinux.org>

pkgname=pax
pkgver=20201030
pkgrel=2
pkgdesc='Portable Archive Interchange - the POSIX standard archive tool for cpio and tar formats'
arch=('x86_64')
url='https://www.mirbsd.org/pax.htm'
license=('BSD')
depends=('glibc')
source=("https://www.mirbsd.org/MirOS/dist/mir/cpio/paxmirabilis-${pkgver}.cpio.gz")
noextract=("paxmirabilis-${pkgver}.cpio.gz")
sha256sums=('fe3f99c28ba7a46c4bce0b329da3742908b87fe8fbe17f0db1f99a1bd053d46b')

prepare() {
    mkdir -p "${pkgname}-${pkgver}/build"
    bsdtar -x -f "paxmirabilis-${pkgver}.cpio.gz" -C "$pkgname-${pkgver}" --strip-components='1'
}

build() {
    cd "${pkgname}-${pkgver}/build"
    sh ../Build.sh -r -tpax
    
    # license
    sed -n '5,36p' ../pax.h > LICENSE # create file
    sed -i '1,32s/^.\{,3\}//' LICENSE # erase C comments
}

package(){
    # executables
    install -D -m755 "${pkgname}-${pkgver}/build/pax" -t "${pkgdir}/usr/bin"
    ln -s pax "${pkgdir}/usr/bin/paxcpio"
    ln -s pax "${pkgdir}/usr/bin/paxtar"
    
    # man pages
    install -D -m644 "${pkgname}-${pkgver}/build/mans/"*.1 -t "${pkgdir}/usr/share/man/man1"
    
    # license
    install -D -m644 "${pkgname}-${pkgver}/build/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
}