1 Topic by aloniv (edited by aloniv Yesterday 06:58:55)

  • aloniv
  • Hyper Expert
  • Offline
  • Registered: 2018-08-16
  • Posts: 156

Topic: NZBGet (an NZB usenet downloader) can be installed in Hyperbola

I noticed that no NZB usenet downloader was available in Hyperbola and I remembered using NZBGet in the past.

The PKGBUILD needed is based on the official Arch one - one just needs to disable openssl, remove the systemd path and rename unrar to unar:
https://archlinux.org/packages/extra/x86_64/nzbget/

PKGBUILD

# Maintainer: Jaroslav Lichtblau <svetlemodry@archlinux.org>
# Maintainer: Carl Smedstad <carsme@archlinux.org>
# Contributor: Alexander Rødseth <rodseth@gmail.com>

pkgname=nzbget
pkgver=25.4
pkgrel=2
pkgdesc="Efficient usenet downloader"
arch=('x86_64')
url="https://nzbget.com"
license=('GPL-2.0-or-later')
depends=(
  'boost-libs'
  'gcc-libs'
  'glibc'
  'libxml2'
  'ncurses'
  'zlib'
)
makedepends=(
  'boost'
  'cmake'
  'git'
)
optdepends=(
  'python: to run included scripts'
  'unar: unpacking archives'
  '7zip: unpacking archives'
)
source=(
  "https://github.com/nzbgetcom/nzbget/archive/v$pkgver/$pkgname-$pkgver.tar.gz"
  "git+https://github.com/nzbgetcom/par2cmdline-turbo.git"
  "$pkgname-use-par2cmdline-turbo-from-sources.patch"
)
sha256sums=('2603116ffaef4992621cf7a82ce300f41a676a312de784f2bac5058abc1a2385'
            'SKIP'
            '9608a7166969593fea35c2db61a788a0c0083dece1907fcc33c978c70226ff0a')

prepare() {
  cd $pkgname-$pkgver
  patch -Np1 < ../$pkgname-use-par2cmdline-turbo-from-sources.patch
}

build() {
  cd $pkgname-$pkgver
  cmake -S . -B build \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -Wno-dev \
    -DENABLE_TESTS=ON \
    -DDISABLE_TLS=ON
  cmake --build build
}

check() {
  cd $pkgname-$pkgver
  ctest --test-dir build --output-on-failure
}

package() {
  cd $pkgname-$pkgver
  DESTDIR="$pkgdir" cmake --install build
  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" ./*.md
}

nzbget-use-par2cmdline-turbo-from-sources.patch

diff --unified --recursive --text --new-file nzbget-25.3.orig/cmake/par2-turbo.cmake nzbget-25.3/cmake/par2-turbo.cmake
--- nzbget-25.3.orig/cmake/par2-turbo.cmake    2025-09-01 20:50:58.443363400 +0200
+++ nzbget-25.3/cmake/par2-turbo.cmake    2025-09-01 20:51:31.722598503 +0200
@@ -51,7 +51,7 @@
 ExternalProject_add(
     par2-turbo
     PREFIX            par2-turbo
-    GIT_REPOSITORY    https://github.com/nzbgetcom/par2cmdline-turbo.git
+    GIT_REPOSITORY    file://${CMAKE_SOURCE_DIR}/../par2cmdline-turbo
     GIT_TAG            v1.3.0-20250808
     TLS_VERIFY        TRUE
     GIT_SHALLOW        TRUE

2 Reply by throgh

  • throgh
  • throgh
  • Package Development and Community Coordinator
  • Offline
  • From: Planet Earth
  • Registered: 2017-12-28
  • Posts: 3,058

Re: NZBGet (an NZB usenet downloader) can be installed in Hyperbola

Thanks, moved the posting: https://forums.hyperbola.info/viewtopic … 8671#p8671

Human being in favor with clear principles and so also for freedom in soft- and hardware!

Certainly anyone who has the power to make you believe absurdities has the power to make you commit injustices: For a life of every being full with peace and kindness, including diversity and freedom. Capitalism is destroying our minds, the planet itself and the universe in the end!