Hello together,

as mentioned in the concurrent issue SMPlayer has got settings for usage with Chromecast. So I've added patchsets to the current package for the removal:

# Maintainer (Arch): Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor (Arch): Ionut Biru <ibiru@archlinux.org>
# Contributor (Arch): Allan McRae <allan@archlinux.org>
# Contributor (Arch): Alessio 'mOLOk' Bolognino <themolok@gmail.com>
# Contributor (Arch): shamrok <szamrok@gmail.com>
# Maintainer (Parabola): Omar Vega Ramos <ovruni@gnu.org.pe>
# Maintainer: André Silva <emulatorman@hyperbola.info>

pkgname=smplayer
pkgver=17.4.2
_debver=17.3.0
_debrel=1
pkgrel=1.hyperbola4
pkgdesc='Media player with built-in codecs that can play virtually all video and audio formats, without nonfree support, no proprietary chromecast and with hypervideo support'
url='http://smplayer.sourceforge.net/'
arch=('i686' 'x86_64')
license=('GPL')
depends=('qt5-script' 'mpv' 'hicolor-icon-theme')
makedepends=('qt5-tools' 'quilt')
optdepends=('smplayer-themes: icon themes collection'
            'smplayer-skins: skin themes collection'
            'hypervideo: youtube videos and streaming'
            'mplayer: alternative multimedia engine')
source=(https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.bz2
        https://debian.simnet.is/debian/pool/main/s/smplayer/smplayer_$_debver~ds0-$_debrel.debian.tar.xz
        add-missing-QClipboard-include.patch
        libre.patch)
sha512sums=('bb0169dc1e2d6b56f3617986647664eda677229bce5b2aa898b64574319a84ac4d51c78f5a68ab57df5dce48c1f76d0d9e0dbdefa5baee351c0a22c2a9cb5186'
            '43982b8c97766b31fff1e6387e31455c47a070460f1d40d25eab17c5035d443e9d09070850f635ed8ef857c64f37bb124c2e16d69c1cbe92744ae576beca0f3f'
            '619b8a236b36518bf0f9984d87384d9c5be10fdbda17598d57736064c0c2d6d9f920c9d3f1eb059ba390670ec28559f0dda6f85757ef8696540c424b08863e39'
            '4f1384395a39abb8b65aa81558372177452bb7d9780af9dfa492db9f1b3fc93d258af2081a19f72bfee37899277fd7b487a616a73c04eaca8ea63925e0c96290')

prepare() {
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  # add missing QClipboard include
  patch -p1 -i ${srcdir}/add-missing-QClipboard-include.patch

  # disable SMTube support and rename youtube-dl to hypervideo
  patch -p1 -i ${srcdir}/libre.patch

  # fix GNU/Linux name
  sed -i 's|Linux|GNU/Linux|' src/smplayer.cpp
}

build() {
  cd ${pkgname}-${pkgver}
  make PREFIX=/usr \
    DOC_PATH="\\\"/usr/share/doc/smplayer\\\"" \
    QMAKE_OPTS=DEFINES+=NO_DEBUG_ON_CONSOLE
}

package() {
  cd ${pkgname}-${pkgver}
  make DOC_PATH=/usr/share/doc/smplayer \
    DESTDIR="${pkgdir}" PREFIX=/usr install
}

# vim: ts=2 sw=2 et:

The file libre.patch is too long for posting here: https://hastebin.com/raw/ipafosuqab