51 Reply by throgh

  • throgh
  • throgh
  • Package Development
  • Offline
  • From: Planet Earth
  • Registered: 2017-12-28
  • Posts: 3,135

Re: [Collection] Compilation of packages and ports (not in repositories)

Package catgirl

PKGBUILD

# Maintainer (Arch): Sebastian LaVine <mail@smlavine.com>
# Contributor (Arch): lillian rose winter <hi@neko.vg>
# Contributor (Arch): Evan McCarthy <evan@mccarthy.mn>
# Maintainer: Tobias Dausend <throgh@hyperbola.info>

pkgname=catgirl
_pkgver=2.2a
pkgver=2.2.a
pkgrel=1
pkgdesc="TLS-only terminal IRC client"
arch=('i686' 'x86_64')
url='https://git.causal.agency/catgirl/'
license=('GPL-3')
depends=('libressl' 'ncurses')
source=("https://git.causal.agency/${pkgname}/snapshot/${pkgname}-${_pkgver}.tar.gz")
sha512sums=('988750c960630ec8314ebde7b9802f8b6a3087f733359f61f49c4f83cb6e327c03cde9ad88f2cb535d56ead1376cd121a7124c367c90394a6d4d7f80b25e329f')

build() {
  cd "${pkgname}-${_pkgver}"
  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man
  make all
}

package() {
  cd "${pkgname}-${_pkgver}"
  make DESTDIR="$pkgdir/" install
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/$pkgname"
}
Human being in favor with clear principles and so also for freedom in soft- and hardware!

Certainly anyone who has the power to make you believe absurdities has the power to make you commit injustices: For a life of every being full with peace and kindness, including diversity and freedom. Capitalism is destroying our minds, the planet itself and the universe in the end!

52 Reply by Allen123456hello (edited by Allen123456hello 2026-05-04 15:05:03)

  • Allen123456hello
  • Member
  • Offline
  • From: Earth
  • Registered: 2026-01-17
  • Posts: 31

Re: [Collection] Compilation of packages and ports (not in repositories)

May be an alternative to pkg-config: pkgconf

# Maintainer: Allen123456hello

pkgname=pkgconf
pkgver=2.5.1
pkgrel=1
pkgdesc="A newer system for managing library compile/link flags"
url="https://github.com/pkgconf/pkgconf"
license=(ISC)
arch=(i686 x86_64)
depends=(glibc)
provides=(pkg-config pkgconfig)
conflicts=(pkg-config)
source=("https://distfiles.ariadne.space/pkgconf/${pkgname}-${pkgver}.tar.xz")
sha512sums=('e654c3a460e5f0f801e8ac43ad9086f397d1da0553186ff05f5f0e18ffdac99fb652fd9b6c0379db4bc8307699699d69bc66d13cc85a4a6b0cd36462f5948a1d')

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --disable-static --docdir=/usr/share/doc/$pkgname-$pkgver 
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  ln -sv pkgconf "$pkgdir/usr/bin/pkg-config"
  ln -sv pkgconf.1 "$pkgdir/usr/share/man/man1/pkg-config.1"
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}